// Top-level build file where you can add configuration options common to all sub-projects/modules.
def PDRONE_MAVEN_URL = "https://pdrone.vipera.com//maven/af2ce13b-360b-47a2-b2c5-05b6d2e6db1c"
def PDRONDE_SERVER_ID = "pdrone.af2ce13b-360b-47a2-b2c5-05b6d2e6db1c"


cdvPluginPostBuildExtras.add({
  android {
      compileOptions {
          sourceCompatibility JavaVersion.VERSION_1_7
          targetCompatibility JavaVersion.VERSION_1_7
      }
      allprojects {
          compileOptions {
              sourceCompatibility = JavaVersion.VERSION_1_7
              targetCompatibility = JavaVersion.VERSION_1_7
          }
      }
  }
})


buildscript {
    repositories {
        maven {
            url 'https://maven.google.com'
        }
        jcenter()
        mavenLocal()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.2'
    }
}

def getMavenSettingsCredentials = {
    String userHome = System.getProperty( "user.home" );
    File mavenSettings = new File(userHome, ".m2/settings.xml")
    def xmlSlurper = new XmlSlurper()
    def output = xmlSlurper.parse(mavenSettings)
    return output."servers"."server"
}

def getCredentials = {
    def entries = getMavenSettingsCredentials()
    for (entry in entries) {
        if ( entry."id".text() == PDRONDE_SERVER_ID ) {
            return [username: entry.username.text(), password: entry.password.text()]
        }
    }
}


allprojects {
    repositories {
        maven {
            url 'https://maven.google.com'
        }
        jcenter()
        mavenCentral()
        maven {
            def cred= getCredentials()
            credentials {
                username cred['username']
                password cred['password']
            }
            url(PDRONE_MAVEN_URL)
        }

    }
}

dependencies {
  compile ('com.vipera.de:apprating:0.2.1'){
      exclude group: 'com.android.support', module: 'appcompat-v7'
  }
}